EXCEL VBAを使ってAutoCADの線分(line)を描く方法

Sub DrawLineInAutoCAD()
  'AutoCADアプリケーションオブジェクトを宣言
  Dim acadApp As Object
  'AutoCADドキュメントオブジェクトを宣言
  Dim acadDoc As Object
  'ラインオブジェクトを宣言
  Dim lineObj As Object
  
  'AutoCADが起動していなければ起動し、すでに開いていたら取得する。
  On Error Resume Next
  Set acadApp = GetObject(,"AutoCAD.Application")
  If acadApp Is Nothing Then
    Set acadApp = CreateObject("AutoCAD.Application")
  End If
  On Error GoTo 0
  
  'AutoCADを表示
  acadApp.Visible = True
  
  'AutoCADドキュメントが開いてなければ新規作成し、開いていれば取得する。
  On Error Resume Next
  Set acadDoc = acadApp.ActiveDocument
  If acadDoc Is Nothing Then
    Set acadDoc = acadApp.Documents.Add
  End If
  On Error GoTo 0 
  
  '始点と終点を入れる変数の宣言
  Dim startPoint(0 To 2) As Double
  Dim endPoint(0 To 2) As Double
  
  '始点を設定
  startPoint(0) = Cells(2,1) 'X座標
  startPoint(1) = Cells(2,2) 'Y座標
  startPoint(2) = Cells(2,3) 'Z座標
  
  '終点を設定
  endPoint(0) = Cells(2,4) 'X座標
  endPoint(1) = Cells(2,5) 'Y座標
  endPoint(2) = Cells(2,6) 'Z座標  
  
  '線分を作成
  Set lineObj = acadDoc.ModelSpace.AddLine(startPoint, endPoint)
  
  'ハンドルの取得
  Cells(2,7) = lineObj.Handle
  
  'オブジェクト範囲の表示
  acadDoc.Application.ZoomExtents
  
  '再作図
  acadDoc.Regen acActiveViewport
  
  'メッセージを表示
  MsgBox ”線分を描きました！”
  
End Sub
  

Public acadApp As AcadApplication       'AutoCADのアプリケーションドキュメントを保持する変数
Public acadDoc As AutoCAD.AcadDocument  'AutoCADのドキュメントオブジェクトを保持する変数

Function DrawLineInAutoCAD(x1 As Double, y1 As Double, z1 As Double, x2 As Double, y2 As Double, z2 As Double) As String
  'AutoCADに線を描画する関数
  '引数は最初から順に
  '始点のX座標、始点のY座標、始点のZ座標、終点のX座標、終点のY座標、終点のZ座標
  '戻り値は描画した線分のハンドル
  
  Dim lineObj As AcadLine '線分オブジェクトを保持する変数
  
  Dim startPoint(2) As Double, endPoint(2) As Double '始点と終点の座標を保持する配列
  
  '始点の座標を設定
  startPoint(0) = x1
  startPoint(1) = y1
  startPoint(2) = z1
  
  '終点の座標を設定
  endPoint(0) = x2
  endPoint(1) = y2
  endPoint(2) = z2
  
  'AutoCADのモデル空間に線を追加
  Set lineObj = acadDoc.ModelSpace.AddLine(startPoint, endPoint)
  
  '追加した線分のハンドルを返す
  DrawLineInAutoCAD = lineObj.Handle
  
End Function

public Sub main()
  On Error GoTo OUT1 'エラーハンドリング：AutoCADが起動していないとき
  Set acadApp =GetObject（,"AutoCAD.Application") '既存のAutoCADアプリケーションの取得
  
  On Error GoTo OUT2 'エラーハンドリング：AutoCADのファイルが開かれてない場合
  Set acadDoc = acadApp.ActiveDocument 'アクティブなAutoCADドキュメントを取得
  
  On Error GoTo 0 'エラーハンドリングをリセット
  
  'AutoCADに線分を描画し、そのハンドルをExcelに書き込む
  Cells(2,7) = DrawLineInAutoCAD(Cells(2,1),Cells(2,2),Cells(2,3),Cells(2,4),Cells(2,5),Cells(2,6))
  Cells(3,7) = DrawLineInAutoCAD(Cells(3,1),Cells(3,2),Cells(3,3),Cells(3,4),Cells(3,5),Cells(3,6))  
  Cells(4,7) = DrawLineInAutoCAD(Cells(4,1),Cells(4,2),Cells(4,3),Cells(4,4),Cells(4,5),Cells(4,6))
  
  Exit Sub
OUT1:
  MsgBox "AutoCADを起動してください"
  Exit Sub
OUT2:
　MsgBox "AutoCADのファイルを開いてください"
End Sub

  Cells(2,7) = DrawLineInAutoCAD(1,1,0,10,10,0) '始点(1,1,0)終点(10,10,0)の線を描く

 dummy = DrawLineInAutoCAD(1,1,0,10,10,0) '始点(1,1,0)終点(10,10,0)の線を描く